VBS數(shù)組深入淺出

MyFinoa 2017-10-30

展開全文

VBS數(shù)組在應(yīng)用中沒有像其他語句那么廣泛，VBS數(shù)組存在不少功能上的局限性（如二維數(shù)組的定義、賦值），在使用上也沒有java等語言那么便捷。下面來具體講解下幾個數(shù)組函數(shù)的使用方式：

Array 函數(shù)

返回包含數(shù)組的 Variant。

Array(arglist)

arglist 參數(shù)是賦給包含在 Variant 中的數(shù)組元素的值的列表（用逗號分隔）。如果沒有指定此參數(shù)，則將會創(chuàng)建零長度的數(shù)組。

說明

用于引用數(shù)組元素的表示符，由跟隨有括號的變量名組成，括號中包含指示所需元素的索引號。在下面的示例中，第一條語句創(chuàng)建名為 A 的變量。第二條語句將一個數(shù)組賦值給變量 A。最后一條語句將包含在第二個數(shù)組元素中的值賦值給另一個變量。

arr = array("t1","t2")
MsgBox arr(0)
MsgBox arr(1)

注意未作為數(shù)組聲明的變量仍可以包含數(shù)組。雖然包含數(shù)組的 Variant 變量與包含 Variant 元素的數(shù)組變量有概念上的不同，但訪問數(shù)組元素的方法是相同的。

IsArray 函數(shù)

返回 Boolean 值指明某變量是否為數(shù)組。

  IsArray(varname)

varname 參數(shù)可以是任意變量。

說明

如果變量是數(shù)組，IsArray 函數(shù)返回 True；否則，函數(shù)返回 False。當(dāng)變量中包含有數(shù)組時，使用 IsArray 函數(shù)很有效。

下面的示例利用 IsArray 函數(shù)驗證 MyVariable 是否為一數(shù)組：

Dim MyVariable
Dim MyArray(3)
MyArray(0) = "Sunday"
MyArray(1) = "Monday"
MyArray(2) = "Tuesday"
MyVariable = IsArray(MyArray) ' MyVariable 包含 "True"。

UBound 函數(shù)

返回指定數(shù)組維數(shù)的最大可用下標(biāo)。

  UBound(arrayname[, dimension])

參數(shù)

arrayname

必選項。數(shù)組變量名，遵循標(biāo)準(zhǔn)變量命名規(guī)則。

Dimension

可選項。指定返回哪一維上界的整數(shù)。1 表示第一維，2 表示第二維，以此類推。如果省略 dimension 參數(shù)，則默認(rèn)值為 1。

說明

UBound 函數(shù)與 LBound 函數(shù)一起使用，用于確定數(shù)組的大小。使用 LBound 函數(shù)可以確定數(shù)組某一維的下界。

所有維的下界均為 0。對于有這樣維數(shù)的數(shù)組，UBound 函數(shù)返回以下結(jié)果：

   Dim A(100,3,4)

語句	返回值
UBound(A, 1)	100
UBound(A, 2)	3
UBound(A, 3)	4

LBound 函數(shù)

返回指定數(shù)組維的最小可用下標(biāo)。

  LBound(arrayname[, dimension])

參數(shù)

arrayname

數(shù)組變量名，遵循標(biāo)準(zhǔn)變量命名規(guī)則。

Dimension

指明要返回哪一維下界的整數(shù)。使用 1 表示第一維，2 表示第二維，以此類推。如果省略 dimension 參數(shù)，默認(rèn)值為 1。

說明

LBound 函數(shù)與 UBound 函數(shù)共同使用以確定數(shù)組的大小。使用 UBound 函數(shù)可以找到數(shù)組某一維的上界。任一維的下界都是 0。

arr = array("t1","t2","t3")
For i=0 To UBound(arr)-LBound(arr)
    MsgBox arr(i)
Next

Split 函數(shù)

返回基于 0 的一維數(shù)組，其中包含指定數(shù)目的子字符串。

   Split(expression[, delimiter[, count[, start]]])

參數(shù)

expression

必選項。字符串表達(dá)式，包含子字符串和分隔符。如果 expression 為零長度字符串，Split 返回空數(shù)組，即不包含元素和數(shù)據(jù)的數(shù)組。

delimiter

可選項。用于標(biāo)識子字符串界限的字符。如果省略，使用空格 ("") 作為分隔符。如果 delimiter 為零長度字符串，則返回包含整個 expression 字符串的單元素數(shù)組。

count

可選項。被返回的子字符串?dāng)?shù)目，-1 指示返回所有子字符串。

Compare

可選項。指示在計算子字符串時使用的比較類型的數(shù)值。有關(guān)數(shù)值，請參閱“設(shè)置”部分。

設(shè)置

compare 參數(shù)可以有以下值：

常數(shù)	值	描述
vbBinaryCompare	0	執(zhí)行二進(jìn)制比較。
vbTextCompare	1	執(zhí)行文本比較。

說明

下面的示例利用 Split 函數(shù)從字符串中返回數(shù)組。函數(shù)對分界符進(jìn)行文本比較，返回所有的子字符串。

Dim MyString, MyArray, Msg
MyString = "VBScriptXisXfun!"
MyArray = Split(MyString, "x", -1, 1)
' MyArray(0) 包含 "VBScript"。
' MyArray(1) 包含 "is"。
' MyArray(2) 包含 "fun!"。
Msg = MyArray(0) & " " & MyArray(1)
Msg = Msg   & " " & MyArray(2)
MsgBox Msg

再如：
stng = "t1,t2,t3"
arr = Split(stng,",")
MsgBox arr(0)
MsgBox arr(1)
MsgBox arr(2)

Join 函數(shù)

返回一個字符串，此字符串由包含在數(shù)組中的許多子字符串連接創(chuàng)建。

  Join(list[，delimiter])

參數(shù)

list

必選項。包含要連接的子字符串一維數(shù)組。

Delimiter

可選項。在返回字符串中用于分隔子字符串的字符。如果省略，將使用空字符 ("")。如果 delimiter 是零長度字符串，則在同一列表中列出全部項，沒有分界符。

下面的示例利用 Join 函數(shù)聯(lián)合 MyArray 的子字符串：

Dim MyString
Dim MyArray(3)
MyArray(0) = "Mr."
MyArray(1) = "John "
MyArray(2) = "Doe "
MyArray(3) = "III"
MyString = Join(MyArray) 'MyString 包含 "Mr. John Doe III"。

再如：
arr = array("t1","t2","t3")
MsgBox Join(arr,",")

上面主要對VBS中的相關(guān)函數(shù)進(jìn)行了介紹，在實際工作中還經(jīng)常會遇到一些特殊的處理，并且都十分的實用，下面一一進(jìn)行舉例說明：

例一：一維數(shù)組的比較

Dim a
Dim b
a=Array(10,15,30)
b=Array(10,20,30)                     
flag=1
For i=0 To UBound(a)-LBound(a)
        If a(i)=b(i) Then
            flag=1
        Else
            flag=0
            n=UBound(a)
            msgbox "數(shù)組a"&n&":="&a(i)&","&"數(shù)組b"&n&":="&b(i)
        End If
Next

例二：二維數(shù)組的比較

Dim array1(1,1)
array1(0,0)=1
array1(0,1)=2
array1(1,0)=3
array1(1,1)=4
Dim array2(1,1)
array2(0,0)=1
array2(0,1)=2
array2(1,0)=4
array2(1,1)=4
                  
flag=1
For i=0 To 1
    For j=0 To 1
        If array1(i,j)=array2(i,j) Then
            flag=1
            Exit for
        Else
            flag=0
            msgbox "array1"&"("&i&","&j&")"&"="&array1(i,j)&","&"array2"&"("&i&","&j&")"&"="&array2(i,j)
        End If
    Next
Next

例三：使用循環(huán)來比較數(shù)組里是否包含某值

Dim arr, i, str
arr = array(0, 1, 2, 3, 4, 5, 6, 7, 8, 9, "a", "b", "c", "d", "f", "g")
str = "a"
For i = 0 To UBound(arr)
    If arr(i) = str Then
        Exit For
    end if
Next
If i <= UBound(arr) Then
    msgbox  "arr中包含str的值！"
    Else
    msgbox  "arr中不包含str的值！"
End If

例四：使用函數(shù)組合來比較數(shù)組里是否包含某值（優(yōu)化邏輯）

Dim arr, i, str
arr = array(0, 1, 2, 3, 4, 5, 6, 7, 8, 9, "a", "b", "c", "d", "f", "g")
str = "a"
If InStr(Join(arr, "|"), str) > 0 Then
    msgbox  "arr中包含str的值！"
    Else
    msgbox  "arr中不包含str的值！"
End If

靈活應(yīng)用各種函數(shù)命令，可以節(jié)約大量的多余代碼，不僅精簡代碼結(jié)構(gòu)，提供執(zhí)行效率。

例五：VBS中數(shù)組作為函數(shù)的返回值

Function GenerateRandom()
   Dim myarray(2)
   Dim aa, bb, cc
   Dim myvalue, bbbase, ccbase 
   bbbase=array("Beijing", "NewYork", "Copenhagen", "Paris", "London", "Gothenborg")
   ccbase=array("China", "America", "Denmark", "Franch", "England", "Sweden")
  'Get a number contains 8 characters
   aa= Int((99999999 - 11111111+ 1) * Rnd + 11111111)
  ' Get a number between 1 to 6
   myvalue=Int((6 * Rnd) + 1)
   bb=bbbase(myvalue)
   cc=ccbase(myvalue)
   myarray(0)=CStr(aa)
   myarray(1)=bb
   myarray(2)=cc 
  GenerateRandom=myarray  
 End Function
'****************************************************
' Call the function 
Dim testarr 
testarr=GenerateRandom
msgbox testarr(0)
msgbox testarr(1) 
msgbox testarr(2)

例六：數(shù)組排序

Function fSortArray(aSortThisArray)
   Dim oArrayList, iElement
   Set oArrayList = CreateObject( "System.Collections.ArrayList" )
   For iElement = 0 To UBound(aSortThisArray)
       oArrayList.Add aSortThisArray(iElement)
    Next
    oArrayList.Sort
    set fSortArray = oArrayList
End Function
 
myarray=Array(50,20,30)
MsgBox myarray(0)
MsgBox fSortArray(myarray)(0)
 
'CreateObject( "System.Collections.ArrayList" )調(diào)用了mscoree.dll,是.NET Framework相關(guān)組件。