WebBrowser技巧大全

sumstars 2014-11-19

展開全文

在webbrowser中查找字符串并定位

procedure TForm1.WebFindText;
const
CLSID_WebBrowser: TGUID = '{ED016940-BD5B-11cf-BA4E-00C04FD70816}';
var
CmdTarget: IOleCommandTarget;
begin
try
WebBrowser1.Document.QueryInterface(IOleCommandTarget, CmdTarget);
if CmdTarget <> nil then
try
CmdTarget.Exec(@CLSID_WebBrowser, 1, 0, EmptyParam, EmptyParam);
finally
CmdTarget._Release;
end;
except
end;
end;

===================================================================================
Twebbrowser里如何保存里面的網(wǎng)頁內(nèi)容？
WebBrowser1.ExecWB(OLECMDID_SAVEAS,OLECMDEXECOPT_DODEFAULT, EmptyParam,
EmptyParam);
這幾個參數(shù)不用說了吧
==============================================================
如何用程序復(fù)制webbrows的內(nèi)容
來自：xwhjq, 時間：2002-12-10 19:36:00, ID：1500365
if WebBrowser1.Document <> nil then
begin
WebBrowser1.ExecWB(OLECMDID_selectall,OLECMDEXECOPT_DODEFAULT);
WebBrowser1.ExecWB(OLECMDID_COPY,OLECMDEXECOPT_DODEFAULT);
end;
==============================================================
引入OleCtrls和Activex單元
IE.ExecWB(OLECMDID_PRINT,OLECMDEXECOPT_DODEFAULT,a,b);
//webbrowser1.ExecWB(OLECMDID_PRINT, OLECMDEXECOPT_PROMPTUSER);
//webbrowser1.ExecWB(OLECMDID_SAVEAS,OLECMDEXECOPT_PROMPTUSER);
//WebBrowser1.ExecWB(OLECMDID_PASTE,OLECMDEXECOPT_DODEFAULT);
//WebBrowser1.ExecWB(OLECMDID_COPY,OLECMDEXECOPT_DODEFAULT);
//WebBrowser1.ExecWB(OLECMDID_ZOOM,OLECMDEXECOPT_DONTPROMPTUSER,pvaIn,pvaOut);
==================================================================================
來自：zw84611, 時間：2002-11-19 9:53:00, ID：1441206
unit Unit1;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
StdCtrls, ComCtrls, OleCtrls, SHDocVw, Activex;

type
TForm1 = class(TForm)
RichEdit1: TRichEdit;
WebBrowser1: TWebBrowser;
Button1: TButton;
procedure FormCreate(Sender: TObject);
procedure Button1Click(Sender: TObject);
procedure WebBrowser1NavigateComplete2(Sender: TObject;
const pDisp: IDispatch; var URL: OleVariant);
private
{ Private declarations }
public
{ Public declarations }
end;

var
Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.FormCreate(Sender: TObject);
begin
///RichEdit1.Lines.SaveToFile('a.txt');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
WebBrowser1.Navigate('c:\序言.htm');
end;

procedure TForm1.WebBrowser1NavigateComplete2(Sender: TObject;
const pDisp: IDispatch; var URL: OleVariant);
begin

RichEdit1.PlainText := true;
webbrowser1.ExecWB(OLECMDID_SELECTALL,0);
webbrowser1.ExecWB(OLECMDID_COPY,0);
richedit1.PasteFromClipboard;
RichEdit1.Lines.SaveToFile('c:\ab.txt');

end;
//注意下面
initialization
OleInitialize(nil);

finalization
OleUninitialize;

end.
=====================================================================================
TWebBrowser編程簡述
發(fā)表日期：2005-10-17 作者：[轉(zhuǎn)貼] 出處：

１、初始化和終止化（Initialization & inalization）

　　大家在執(zhí)行TWebBrowser的某個方法以進行期望的操作，如ExecWB等的時候可能都碰到過“試圖激活未注冊的丟失目標”或“OLE對象未注冊”等錯誤，或者并沒有出錯但是得不到希望的結(jié)果，比如不能將選中的網(wǎng)頁內(nèi)容復(fù)制到剪貼板等。以前用它編程的時候，我發(fā)現(xiàn)ExecWB有時侯起作用但有時侯又不行，在Delphi生成的缺省工程主窗口上加入TWebBrowser，運行時并不會出現(xiàn)“OLE對象未注冊”的錯誤。同樣是一個偶然的機會，我才知道OLE對象需要初始化和終止化（懂得的東東實在太少了）。
　　我用我的前一篇文章《Delphi程序窗口動畫&正常排列平鋪的解決》所說的方法編程，運行時出了上面所說的錯誤，我便猜想應(yīng)該有OleInitialize之類的語句，于是，找到并加上了下面幾句話，終于搞定！究其原因，我想大概是由于TWebBrowser是一個嵌入的OLE對象而不算是用Delphi編寫的VCL吧。

　　initialization
　　　OleInitialize(nil);
　　finalization
　　　try
　　　　OleUninitialize;
　　　except
　　　end;

　　這幾句話放在主窗口所有語句之后，“end.”之前。

--------------------------------------------------------------------------------------------------------

２、EmptyParam

　　在Delphi 5中TWebBrowser的Navigate方法被多次重載：

　　procedure Navigate(const URL: WideString); overload;
　　procedure Navigate(const URL: WideString; var Flags: OleVariant); overload;
　　procedure Navigate(const URL: WideString; var Flags: OleVariant; var TargetFrameName: 　　　　OleVariant); overload;
　　procedure Navigate(const URL: WideString; var Flags: OleVariant; var TargetFrameName: 　　　　OleVariant; var PostData: OleVariant); overload;
　　procedure Navigate(const URL: WideString; var Flags: OleVariant; var TargetFrameName: 　　　　OleVariant; var PostData: OleVariant; var Headers: OleVariant); overload;

　　而在實際應(yīng)用中，使用后幾種方法調(diào)用時，由于我們很少用到后面幾個參數(shù)，但函數(shù)聲明又要求是變量參數(shù)，一般的做法如下：

　　var
　　　t:OleVariant;
　　begin
　　　webbrowser1.Navigate(edit1.text,t,t,t,t);
　　end;

　　需要定義變量t（還有很多地方要用到它），很麻煩。其實我們可以用EmptyParam來代替（EmptyParam是一個公用的Variant空變量，不要對它賦值），只需一句話就可以了：

　　webbrowser1.Navigate(edit1.text,EmptyParam,EmptyParam,EmptyParam,EmptyParam);

　　雖然長一點，但比每次都定義變量方便得多。當然，也可以使用第一種方式。

　　webbrowser1.Navigate(edit1.text)

--------------------------------------------------------------------------------------------------------

３、命令操作

　　常用的命令操作用ExecWB方法即可完成，ExecWB同樣多次被重載：

　　procedure ExecWB(cmdID: OLECMDID; cmdexecopt: OLECMDEXECOPT); overload;
　　procedure ExecWB(cmdID: OLECMDID; cmdexecopt: OLECMDEXECOPT; var pvaIn:
　　　　OleVariant); overload;
　　procedure ExecWB(cmdID: rOLECMDID; cmdexecopt: OLECMDEXECOPT; var pvaIn:
　　　　OleVariant; var pvaOut: OleVariant); overload;

　　打開：　彈出“打開Internet地址”對話框，CommandID為OLECMDID_OPEN（若瀏覽器版本為IE5.0，
　　　　　　則此命令不可用）。
　　另存為：調(diào)用“另存為”對話框。
　　　　　　ExecWB(OLECMDID_SAVEAS,OLECMDEXECOPT_DODEFAULT, EmptyParam,
　　　　　　　　　　　EmptyParam);

　　打印、打印預(yù)覽和頁面設(shè)置：　調(diào)用“打印”、“打印預(yù)覽”和“頁面設(shè)置”對話框（IE5.5及以上版本才支持打
　　　　　　　　　　　　　　　　印預(yù)覽，故實現(xiàn)應(yīng)該檢查此命令是否可用）。
　　　　　　ExecWB(OLECMDID_PRINT, OLECMDEXECOPT_DODEFAULT, EmptyParam,
　　　　　　　　　　　EmptyParam);
　　　　　　if QueryStatusWB(OLECMDID_PRINTPREVIEW)=3 then
　　　　　　　ExecWB(OLECMDID_PRINTPREVIEW, OLECMDEXECOPT_DODEFAULT,
　　　　　　　　　　　EmptyParam,EmptyParam);
　　　　　　ExecWB(OLECMDID_PAGESETUP, OLECMDEXECOPT_DODEFAULT, EmptyParam,
　　　　　　　　　　　EmptyParam);

　　剪切、復(fù)制、粘貼、全選：　功能無須多說，需要注意的是：剪切和粘貼不僅對編輯框文字，而且對網(wǎng)頁上的非編
　　　　　　　　　　　　　　　輯框文字同樣有效，用得好的話，也許可以做出功能特殊的東東。獲得其命令使能狀
　　　　　　　　　　　　　　　態(tài)和執(zhí)行命令的方法有兩種（以復(fù)制為例，剪切、粘貼和全選分別將各自的關(guān)鍵字替
　　　　　　　　　　　　　　　換即可，分別為CUT,PASTE和SELECTALL）：
　　　A、用TWebBrowser的QueryStatusWB方法。
　　　　　if(QueryStatusWB(OLECMDID_COPY)=OLECMDF_ENABLED) or
　　　　　　OLECMDF_SUPPORTED) then
　　　　　　ExecWB(OLECMDID_COPY, OLECMDEXECOPT_DODEFAULT, EmptyParam,
　　　　　　　　　　　EmptyParam);
　　　B、用IHTMLDocument2的QueryCommandEnabled方法。
　　　　　var
　　　　　　Doc: IHTMLDocument2;
　　　　　begin
　　　　　　Doc :=WebBrowser1.Document as IHTMLDocument2;
　　　　　　if Doc.QueryCommandEnabled('Copy') then
　　　　　　　Doc.ExecCommand('Copy',false,EmptyParam);
　　　　　end;

　　查找：　參考第九條“查找”功能。

--------------------------------------------------------------------------------------------------------

４、字體大小

　　類似“字體”菜單上的從“最大”到“最小”五項（對應(yīng)整數(shù)0～4，Largest等假設(shè)為五個菜單項的名字，Tag 屬性分別設(shè)為0～4）。
　　　A、讀取當前頁面字體大小。
　　　　　var
　　　　　　t: OleVariant;
　　　　　Begin
　　　　　　WebBrowser1.ExecWB(OLECMDID_ZOOM, OLECMDEXECOPT_DONTPROMPTUSER,
　　　　　　　EmptyParam,t);
　　　　　　case t of
　　　　　　4: Largest.Checked :=true;
　　　　　　3: Larger.Checked :=true;
　　　　　　2: Middle.Checked :=true;
　　　　　　1: Small.Checked :=true;
　　　　　　0: Smallest.Checked :=true;
　　　　　　end;
　　　　　end;
　　　B、設(shè)置頁面字體大小。
　　　　　Largest.Checked :=false;
　　　　　Larger.Checked :=false;
　　　　　Middle.Checked :=false;
　　　　　Small.Checked :=false;
　　　　　Smallest.Checked :=false;
　　　　　TMenuItem(Sender).Checked :=true;
　　　　　t :=TMenuItem(Sender).Tag;
　　　　　WebBrowser1.ExecWB(OLECMDID_ZOOM, OLECMDEXECOPT_DONTPROMPTUSER,
　　　　　　t,t);

--------------------------------------------------------------------------------------------------------

５、添加到收藏夾和整理收藏夾

　　　　const
　　　　　CLSID_ShellUIHelper: TGUID = '{64AB4BB7-111E-11D1-8F79-00C04FC2FBE1}';

　　　　var
　　　　　p:procedure(Handle: THandle; Path: PChar); stdcall;

　　　　procedure TForm1.OrganizeFavorite(Sender: Tobject);
　　　　var
　　　　　H: HWnd;
　　　　begin
　　　　　H := LoadLibrary(PChar('shdocvw.dll'));
　　　　　if H <> 0 then
　　　　　begin
　　　　p := GetProcAddress(H, PChar('DoOrganizeFavDlg'));
　　　　　　if Assigned(p) then p(Application.Handle, PChar(FavFolder));
　　　　　end;
　　　　　FreeLibrary(h);
　　　　end;
　　　　
　　　　procedure TForm1.AddFavorite(Sender: TObject);
　　　　var
　　　　　ShellUIHelper: ISHellUIHelper;
　　　　　url, title: Olevariant;
　　　　begin
　　　　　Title := Webbrowser1.LocationName;
　　　　　Url := Webbrowser1.LocationUrl;
　　　　　if Url <> '' then
　　　　　begin
　　　　　　ShellUIHelper := CreateComObject(CLSID_SHELLUIHELPER) as IShellUIHelper;
　　　　　　ShellUIHelper.AddFavorite(url, title);
　　　　　end;
　　　　end;

--------------------------------------------------------------------------------------------------------

６、使WebBrowser獲得焦點

　　TWebBrowser非常特殊，它從TWinControl繼承來的SetFocus方法并不能使得它所包含的文檔獲得焦點，從而不能立即使用Internet Explorer本身具有得快捷鍵，解決方法如下：<

　　procedure TForm1.SetFocusToDoc;
　　begin
　　　if WebBrowser1.Document <> nil then
　　　　with WebBrowser1.Application as IOleobject do
　　　　　DoVerb(OLEIVERB_UIACTIVATE, nil, WebBrowser1, 0, Handle, GetClientRect);
　　end;

　　除此之外，我還找到一種更簡單的方法，這里一并列出：

　　if WebBrowser1.Document <> nil then
　　　IHTMLWindow2(IHTMLDocument2(WebBrowser1.Document).ParentWindow).focus

　　剛找到了更簡單的方法，也許是最簡單的：

　　if WebBrowser1.Document <> nil then
　　　IHTMLWindow4(WebBrowser1.Document).focus

　　還有，需要判斷文檔是否獲得焦點這樣來做：

　　if IHTMLWindow4(WebBrowser1.Document).hasfocus then

--------------------------------------------------------------------------------------------------------

７、點擊“提交”按鈕

　　如同程序里每個窗體上有一個“缺省”按鈕一樣，Web頁面上的每個Form也有一個“缺省”按鈕——即屬性為“Submit”的按鈕，當用戶按下回車鍵時就相當于鼠標單擊了“Submit”。但是TWebBrowser似乎并不響應(yīng)回車鍵，并且，即使把包含TWebBrowser的窗體的KeyPreview設(shè)為True，在窗體的KeyPress事件里還是不能截獲用戶向TWebBrowser發(fā)出的按鍵。
　　我的解決辦法是用ApplicatinEvents構(gòu)件或者自己編寫TApplication對象的OnMessage事件，在其中判斷消息類型，對鍵盤消息做出響應(yīng)。至于點擊“提交”按鈕，可以通過分析網(wǎng)頁源代碼的方法來實現(xiàn)，不過我找到了更為簡單快捷的方法，有兩種，第一種是我自己想出來的，另一種是別人寫的代碼，這里都提供給大家，以做參考。

　　A、用SendKeys函數(shù)向WebBrowser發(fā)送回車鍵
　　　在Delphi 5光盤上的Info\Extras\SendKeys目錄下有一個SndKey32.pas文件，其中包含了兩個函數(shù)SendKeys和AppActivate，我們可以用SendKeys函數(shù)來向WebBrowser發(fā)送回車鍵，我現(xiàn)在用的就是這個方法，使用很簡單，在WebBrowser獲得焦點的情況下（不要求WebBrowser所包含的文檔獲得焦點），用一條語句即可：

　　　Sendkeys('~',true);// press RETURN key

　　　SendKeys函數(shù)的詳細參數(shù)說明等，均包含在SndKey32.pas文件中。

　　B、在OnMessage事件中將接受到的鍵盤消息傳遞給WebBrowser。

　　　procedure TForm1.ApplicationEvents1Message(var Msg: TMsg; var Handled: Boolean);
　　　{fixes the malfunction of some keys within webbrowser control}
　　　const
　　　　StdKeys = [VK_TAB, VK_RETURN]; { standard keys }
　　　　ExtKeys = [VK_DELETE, VK_BACK, VK_LEFT, VK_RIGHT]; { extended keys }
　　　　fExtended = $01000000; { extended key flag }
　　　begin
　　　　Handled := False;
　　　　with Msg do
　　　　if ((Message >= WM_KEYFIRST) and (Message <= WM_KEYLAST)) and
　　　　　((wParam in StdKeys) or
　　　　　{$IFDEF VER120}(GetKeyState(VK_CONTROL) < 0) or {$ENDIF}
　　　　　(wParam in ExtKeys) and
　　　　　((lParam and fExtended) = fExtended)) then
　　　　try
　　　　　if IsChild(Handle, hWnd) then { handles all browser related messages }
　　　　　begin
　　　　　　with {$IFDEF VER120}Application_{$ELSE}Application{$ENDIF} as
　　　　　　　　IOleInPlaceActiveObject do
　　　　　　　Handled := TranslateAccelerator(Msg) = S_OK;
　　　　　　　if not Handled then
　　　　　　　begin
　　　　　　　　Handled := True;
　　　　　　　　TranslateMessage(Msg);
　　　　　　　　DispatchMessage(Msg);
　　　　　　　end;
　　　　　　　end;
　　　　except
　　　　end;
　　　end; // MessageHandler

　?。ù朔椒▉碜訣mbeddedWB.pas）

--------------------------------------------------------------------------------------------------------

８、直接從TWebBrowser得到網(wǎng)頁源碼及Html

　　下面先介紹一種極其簡單的得到TWebBrowser正在訪問的網(wǎng)頁源碼的方法。一般方法是利用TWebBrowser控件中的Document對象提供的IPersistStreamInit接口來實現(xiàn)，具體就是：先檢查WebBrowser.Document對象是否有效，無效則退出；然后取得IPersistStreamInit接口，接著取得HTML源碼的大小，分配全局堆內(nèi)存塊，建立流，再將HTML文本寫到流中。程序雖然不算復(fù)雜，但是有更簡單的方法，所以實現(xiàn)代碼不再給出。其實基本上所有IE的功能TWebBrowser都應(yīng)該有較為簡單的方法來實現(xiàn)，獲取網(wǎng)頁源碼也是一樣。下面的代碼將網(wǎng)頁源碼顯示在Memo1中。

　　　Memo1.Lines.Add(IHtmlDocument2(WebBrowser1.Document).Body.OuterHtml);

　　同時，在用TWebBrowser瀏覽HTML文件的時候要將其保存為文本文件就很簡單了，不需要任何的語法解析工具，因為TWebBrowser也完成了，如下：

　　　Memo1.Lines.Add(IHtmlDocument2(WebBrowser1.Document).Body.OuterText);

--------------------------------------------------------------------------------------------------------

９、“查找”功能

　　查找對話框可以在文檔獲得焦點的時候通過按鍵Ctrl-F來調(diào)出，程序中則調(diào)用IOleCommandTarget對象的成員函數(shù)Exec執(zhí)行OLECMDID_FIND操作來調(diào)用，下面給出的方法是如何在程序中用代碼來做出文字選擇，即你可以自己設(shè)計查找對話框。

　　　var
　　　　Doc: IHtmlDocument2;
　　　　TxtRange: IHtmlTxtRange;
　　　begin
　　　　Doc :=WebBrowser1.Document as IHtmlDocument2;
　　　　Doc.SelectAll;　　　　//此處為簡寫，選擇全部文檔的方法請參見第三條命令操作
　　　　　　　　　　　　　　　　//這句話尤為重要，因為IHtmlTxtRange對象的方法能夠操作的前提是
　　　　　　　　　　　　　　　　//Document已經(jīng)有一個文字選擇區(qū)域。由于接著執(zhí)行下面的語句，所以不會
　　　　　　　　　　　　　　　　//看到文檔全選的過程。
　　　　TxtRange :=Doc.Selection.CreateRange as IHtmlTxtRange;
　　　　TxtRange.FindText('Text to be searched',0.0);
　　　　TxtRange.Select;
　　　end;

　　還有，從Txt.Get_text可以得到當前選中的文字內(nèi)容，某些時候是有用的。

--------------------------------------------------------------------------------------------------------

１０、提取網(wǎng)頁中所有鏈接

　　這個方法來自大富翁論壇hopfield朋友的對一個問題的回答，我本想自己試驗，但總是沒成功。

　　var
　　　doc:IHTMLDocument2;
　　　all:IHTMLElementCollection;
　　　len,i:integer;
　　　item:OleVariant;
　　begin
　　　doc:=WebBrowser1 .Document as IHTMLDocument2;
　　　all:=doc.Get_links;　　　　　　　　　　　　　//doc.Links亦可
　　　len:=all.length;
　　　for i:=0 to len-1 do begin
　　　　item:=all.item(i,varempty);　　　　　　　　//EmpryParam亦可
　　　　memo1.lines.add(item.href);
　　　end;
　　end;

--------------------------------------------------------------------------------------------------------

１１、設(shè)置TWebBrowser的編碼

　　為什么我總是錯過很多機會？其實早就該想到的，但是一念之差，便即天壤之別。當時我要是肯再多考慮一下，多試驗一下，這就不會排到第１１條了。下面給出一個函數(shù)，搞定，難以想象的簡單。

　　procedure SetCharSet(AWebBrowser: TWebBrowser; ACharSet: String);
　　var
　　　RefreshLevel: OleVariant;
　　Begin
　　　IHTMLDocument2(AWebBrowser.Document).Set_CharSet(ACharSet);
　　　RefreshLevel :=7;　　　　　　　　　　　　　　//這個7應(yīng)該從注冊表來，幫助有Bug。
　　　AWebBrowser.Refresh2(RefreshLevel);
　　End;

（出處：http://www./keylife/iblog_show.asp?xid=26988）