語法
COUNTIF(range,criteria)
Range 為需要計(jì)算其中滿足條件的單元格數(shù)目的單元格區(qū)域。
Criteria 為確定哪些單元格將被計(jì)算在內(nèi)的條件，其形式可以為數(shù)字、表達(dá)式、單元格引用或文本。例如，條件可以表示為 32、"32"、">32" 、"apples" 或 B4。
說明
Microsoft Excel 還提供了其他一些函數(shù)，它們可根據(jù)條件來分析數(shù)據(jù)。
若要計(jì)算基于一個(gè)文本字符串或某范圍內(nèi)的一個(gè)數(shù)值的總和，可使用 SUMIF 工作表函數(shù)。
若要使公式返回兩個(gè)基于條件的值之一，例如某指定銷售金額的銷售紅利，可使用 IF 工作表函數(shù)。
若要計(jì)算空或非空單元格的個(gè)數(shù)，可使用 COUNTA 和 COUNTBLANK 函數(shù)。
示例 1：通用 COUNTIF 公式
如果您將示例復(fù)制到空白工作表中，可能會(huì)更易于理解該示例。
A B
1 數(shù)據(jù) 數(shù)據(jù)
2 apples 32
3 oranges 54
4 peaches 75
5 apples 86
公式 說明（結(jié)果）
=COUNTIF(A2:A5,"apples") 計(jì)算第一列中蘋果所在單元格的個(gè)數(shù) (2)
=COUNTIF(A2:A5,A4) 計(jì)算第一列中桃所在單元格的個(gè)數(shù) (2)
=COUNTIF(A2:A5,A3)+COUNTIF(A2:A5,A2) 計(jì)算第一列中柑桔和蘋果所在單元格的個(gè)數(shù) (3)
=COUNTIF(B2:B5,">55") 計(jì)算第二列中值大于 55 的單元格個(gè)數(shù) (2)
=COUNTIF(B2:B5,"<>"&B4) 計(jì)算第二列中值不等于 75 的單元格個(gè)數(shù) (2)
=COUNTIF(B2:B5,">=32")-COUNTIF(B2:B5,">85") 計(jì)算第二列中值大于或等于 32 且小于或等于 85 的單元格個(gè)數(shù) (3)
計(jì)算80到89之間的人數(shù)
=countif(B1:B10,">=80")-countif(B1:B10,">90")
假設(shè)B1:B10為你的數(shù)據(jù)區(qū)域.
2009-11-08 12:20
Excel中能熟練地掌握函數(shù)的技巧，在水文日常工作中能達(dá)到事半功倍的效果。例如：要計(jì)算A1:An(定義：data)區(qū)域中非零的單元格的平均值，可在單元格中輸入=sum(data)/countif(data, "<>0")。下面具體介紹Countif()函數(shù)的高級(jí)技巧如下：
一、求各種類型單元格的個(gè)數(shù)
|
所求類型單元格
|
公式
|
說明
|
|
真空單元格
|
=COUNTIF(data1,"=")
|
|
|
真空+假空單元格
|
=COUNTIF(data1,"")
|
相當(dāng)于countblank()函數(shù)
|
|
非真空單元格
|
=COUNTIF(data1,"<>")
|
相當(dāng)于counta()函數(shù)
|
|
文本型單元格
|
=COUNTIF(data1,"*")
|
假空單元格也是文本型單元格
|
|
區(qū)域內(nèi)所有單元格
|
=COUNTIF(data1,"<>""")
|
|
|
數(shù)字型單元格
|
=COUNT(data1)
|
不是countif()，這里順便點(diǎn)一下。
|
|
備注：data1為用戶定義單元格區(qū)域，如用戶把a(bǔ)1:d50區(qū)域定義為data1，以下data2、data3、data4、data5類同data1，也為用戶定義的單元格區(qū)域。
|
二、求大于或小于等于某個(gè)值的單元格個(gè)數(shù)
|
所求內(nèi)容
|
公式
|
|
大于50
|
=COUNTIF(data2,">50")
|
|
等于50
|
=COUNTIF(data2,50)
|
|
小于50
|
=COUNTIF(data2,"<50")
|
|
大于或等于50
|
=COUNTIF(data2,">=50")
|
|
小于或等于50
|
=COUNTIF(data2,"<=50")
|
|
大于E21單元格的值
|
=COUNTIF(data2,">"&$E$21)
|
|
等于E21單元格的值
|
=COUNTIF(data2,$E$21)
|
|
小于E21單元格的值
|
=COUNTIF(data2,"<"&$E$21)
|
|
大于或等于E21單元格的值
|
=COUNTIF(data2,">="&$E$21)
|
|
小于或等于E21單元格的值
|
=COUNTIF(data2,"<="&$E$21)
|
三、求等于或包含某N個(gè)特定字符的單元格個(gè)數(shù)
|
所求內(nèi)容
|
公式
|
|
兩個(gè)字符
|
=COUNTIF(data3,"??")
|
|
兩個(gè)字符并且第2個(gè)是B
|
=COUNTIF(data3,"?B")
|
|
包含B
|
=COUNTIF(data3,"*B*")
|
|
第2個(gè)字符是B
|
=COUNTIF(data3,"?B*")
|
|
等于“你好”
|
=COUNTIF(data3,"你好")
|
|
包含D38單元格的內(nèi)容
|
=COUNTIF(data3,"*"&D38&"*")
|
|
第2字是D38單元格的內(nèi)容
|
=COUNTIF(data3,"?"&D38&"*")
|
|
備注：countif()函數(shù)對(duì)英文字母不區(qū)分大小寫
|
四、不連續(xù)區(qū)域求個(gè)數(shù)
|
所求內(nèi)容
|
公式
|
|
三個(gè)區(qū)域中>=60
|
=SUM(COUNTIF(INDIRECT({"a1:a10","b2:b20","c3:c30"}),">=60"))
|
|
三個(gè)區(qū)域中=70
|
=SUM(COUNTIF(INDIRECT({"a1:a10","b2:b20","c3:c30"}),70))
|
|
三個(gè)區(qū)域中<60
|
=SUM(COUNTIF(INDIRECT({"a1:a10","b2:b20","c3:c30"}),"<60"))
|
五、兩個(gè)條件求個(gè)數(shù)
|
所求內(nèi)容
|
公式
|
|
>10并且<=15
|
=SUM(COUNTIF(data4,">"&{10,15})*{1,-1})
|
|
>=10并且<15
|
=SUM(COUNTIF(data4,">="&{10,15})*{1,-1})
|
|
>=10并且<=15
|
=SUM(COUNTIF(data4,{">=10",">15"})*{1,-1})
|
|
>10并且<15
|
=SUM(COUNTIF(data4,{">10",">=15"})*{1,-1})
|
|
>10并且<=15
|
=COUNTIF(data4,">10")-COUNTIF(data4,">15")
|
六、數(shù)據(jù)的有效性驗(yàn)證
首先，選擇要設(shè)置有效性驗(yàn)證區(qū)域（如：A1:A100，定義為：data5）中的任一單元格(假設(shè)為：A1)，在excel工作表中，用鼠標(biāo)依次點(diǎn)擊菜單欄數(shù)據(jù)→有效性菜單命令，打開“數(shù)據(jù)有效性”對(duì)話框，在“允許”下拉按鈕中設(shè)置有效性條件為“自定義”，在“公式”框中輸入 =COUNTIF(data5,A1)<2，然后，復(fù)制A1單元格,選中除A1外的所有單元格（A2:A100），用鼠標(biāo)依次點(diǎn)擊編輯→選擇性粘貼命令→粘貼→有效性驗(yàn)證。這樣即實(shí)現(xiàn)了數(shù)據(jù)data5區(qū)域中不重復(fù)的驗(yàn)證條件。
關(guān)于=COUNTIF(F6:N6,"*")的相關(guān)問題:本人在用到公式=COUNTIF(F6:N6,"*")時(shí)，出現(xiàn)錯(cuò)誤，我在所選的區(qū)域內(nèi)（有M、＃、*、和數(shù)字1、0），在用公式求*個(gè)數(shù)時(shí)，所得個(gè)數(shù)為非數(shù)字相加之和，而分別求M、＃、*、1、0個(gè)數(shù)時(shí)得出的個(gè)數(shù)是正確的，同樣的公式為什么求出不同的結(jié)果，很是郁悶，請(qǐng)各位幫忙?。?本來想把表考上，但考不上來。
"*"代表除數(shù)字外的任何符號(hào)，包括兩個(gè)以上的符號(hào)、字符如“#”、“#￥”、“#222”、“B1”、以及以文本方式出現(xiàn)的數(shù)碼“123”等的通配符，但不代表數(shù)字，包括以1.00E+12這樣的方式表示的數(shù)字；所以解決與*號(hào)匹配的問題時(shí)，要在*號(hào)前加~符號(hào)，即“~*”僅代表*號(hào)。公式改為 =COUNTIF(F6:N6,"~*")即可。
|
|
