這組函數(shù)的功能是在主圖或副圖上設(shè)定條件輸出圖象、圖標(biāo)、直線、文字、數(shù)字、指標(biāo)線、指標(biāo)柱等，全部可以單獨使用。

個人感覺，飛狐的強大功能，在此組函數(shù)中有淋漓盡致的發(fā)揮。無論在表面（美感），還是實質(zhì)（提高工作效率）上，都有良好表現(xiàn)。

毫無例外的是，這組函數(shù)中，都帶有COND。CONDITION，條件，狀態(tài)。COND在這里可作為條件理解。

為了能找到合適的COND，用于舉例子，請允許我先介紹一組概念。

高點：在2N+1根K線中，中間這根K線的H，要大于等于左右N根K線的H。在N+1根K線中，有等高點出現(xiàn)，取最先出現(xiàn)的。

低點：在2N+1根K線中，中間這根K線的L，要小于等于左右N根K線的L。在N+1根K線中，有等低點出現(xiàn)，取最先出現(xiàn)的。

峰點：高點和低點，合稱為峰點。

（這個定義，意合于技術(shù)分析的老祖宗道氏：“只要平均指數(shù)的最高點超過了前期的最高點，它就處于牛市時期；當(dāng)最低點低于前期的最低點時，它處于熊市時期。”這里我們撇開向上、向下分形和分形峰狀點等概念，以免把概念復(fù)雜化。）

也為了不讓公式一來就過于復(fù)雜，我們先取N為2來做公式。簡介到后面，可以看到，N是可以作為峰點公式的參數(shù)進行調(diào)整的。

公式名稱：FENG2

公式說明：供引用

公式內(nèi)容：

{峰點參數(shù)暫定為2}

A:=REF(H,2);{中間K線的最高價}

B:=A>=REF(H,4) AND A>=REF(H,3) AND A>=REF(H,1) AND A>=H;{中間K線的最高價大于等于兩邊共四根K線的最高價}

D:=BACKSET(B,3);{將當(dāng)前位置和之前2個周期的數(shù)值設(shè)為1}

HD:FILTER(D,2);{找到高點后，過濾掉其后2周期內(nèi)可能出現(xiàn)的等高點。輸出高點}

A2:=REF(L,2);{中間K線的最低價}

B2:=A2<=REF(L,4) AND A2<=REF(L,3) AND A2<=REF(L,1) AND A2<=L;{中間K線的最低價小于等于兩邊共四根K線的最低價}

D2:=BACKSET(B2,3);{將當(dāng)前位置和之前2個周期的數(shù)值設(shè)為1}

LD:FILTER(D2,2);{找到低點后，過濾掉其后2周期內(nèi)可能出現(xiàn)的等低點。輸出低點}

{后面有些例子，就從這個公式中引用信號。}

一、

函數(shù)： DRAWICON

參數(shù)： 無

用法： DRAWICON(COND,PRICE,TYPE),當(dāng)COND條件滿足時,在PRICE位置畫TYPE號圖標(biāo)。

說明： 在圖形上繪制小圖標(biāo)，其中TYPE可選7種圖標(biāo),編碼為1-7（1-3為小臉，4、5為上下箭頭，6、7為紅綠小旗）。TYPE為　　　 字符串時可顯示用戶自制BMP圖。

示例： DRAWICON(CLOSE>OPEN,LOW,1)；表示當(dāng)收陽時在最低價位置畫1號圖

　　　 DRAWICON(C>O,L,'MyBMP')表示當(dāng)收陽時在最低價位置畫FmlDLL子目錄下的自制圖標(biāo)MyBMP.BMP


1、COND條件，一般是指判斷的結(jié)果，不是0就是1。如用其它數(shù)據(jù)，大于等于1的，條件滿足；小于1，條件就不滿足。

2、TYPE圖標(biāo)，現(xiàn)在已經(jīng)有12種，用下面的公式，在000829上可以全部顯示出來。當(dāng)TYPE取大于等于12的數(shù)時，都顯示黃球。

當(dāng)TYPE取0時，顯示的是笑臉（這個公式中沒有做進去，自己可以試一下）。

B:="FENG2.HD";

D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

A:=D>REF(D,1);

DRAWICON(REF(A,1),1.05*H,1);

DRAWICON(REF(A,2),1.05*H,2);

DRAWICON(REF(A,3),1.05*H,3);

DRAWICON(REF(A,4),1.05*H,4);

DRAWICON(REF(A,5),1.05*H,5);

DRAWICON(REF(A,6),1.05*H,6);

DRAWICON(REF(A,7),1.05*H,7);

DRAWICON(REF(A,8),1.05*H,8);

DRAWICON(REF(A,9),1.05*H,9);

DRAWICON(REF(A,10),1.05*H,10);

DRAWICON(REF(A,11),1.05*H,11);

DRAWICON(REF(A,12),1.05*H,12);

DRAWICON(REF(A,13),1.05*H,13);

DRAWICON(REF(A,14),1.05*H,100);{主圖疊加}

當(dāng)紅球和綠球連續(xù)顯示時，立體感會強一些。

DRAWICON(C>=MA(C,30),MA(C,30),10);

DRAWICON(C<MA(C,30),MA(C,30),11);{主圖疊加}

3、PRICE是用于定位圖標(biāo)的位置的。一般用1.01＊H，或者0.99*L等。現(xiàn)在可用ALIGN(0-5)指定對齊位置。

用這個公式來試（主圖疊加）

B:="FENG2.HD";

D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

A:=D>REF(D,1);

E:=REF(H,1);

DRAWICON(A,E,10),ALIGN0;

DRAWICON(A,E,11),ALIGN1;

DRAWICON(A,E,12),ALIGN2;

DRAWICON(A,E,3),ALIGN3;

DRAWICON(A,E,4),ALIGN4;

DRAWICON(A,E,5),ALIGN5;

可以初步得出結(jié)論：

ALIGN0：信號出現(xiàn)在PRICE的正中；

ALIGN1：信號出現(xiàn)在PRICE下邊（十分靠近）；

ALIGN2：信號出現(xiàn)在PRICE上邊（十分靠近）；

ALIGN3：信號出現(xiàn)在主圖的中間；

ALIGN4：信號出現(xiàn)在主圖的最上邊；

ALIGN5：信號出現(xiàn)在主圖的最下邊；

在高低點上作圖標(biāo)，可以使高低點更明確了。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;{主圖疊加}



4、可以自由調(diào)用MyBMP.BMP圖到顯示位置，大大增強了輸出的效果。你只要看到好看的圖，可以隨時抓拍過來，做成BMP文件，放到FmlDLL子目錄下，就可以調(diào)用了。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,'PIG'),ALIGN1;

DRAWICON(B,H,'PIG'),ALIGN2;{主圖疊加。如果你沒有PIG.BMP文件，則不可顯示。}



DRAWICON(1,MA(C,5),'S28');

DRAWICON(1,MA(C,10),'S31');

DRAWICON(1,MA(C,20),'S14');

DRAWICON(1,MA(C,30),'S25');{主圖疊加。如果你想要這個公式有顯示，可到樓下下載，解壓縮到FmlDLL子目錄下}



內(nèi)有40個不同顏色的小球。

二、

函數(shù)： DRAWLINE

參數(shù)： 無

用法： DRAWLINE(COND1,PRICE1,COND2,PRICE2,EXPAND),當(dāng)COND1條件滿足時,在PRICE1位置畫直線起點，當(dāng)COND2條件滿足時,在PRICE2位置畫直線終點，EXPAND為延長類型。  

說明： 在圖形上繪制直線段。

示例： DRAWILINE(HIGH>=HHV(HIGH,20),HIGH,LOW<=LLV(LOW,20),LOW,1)；表示在創(chuàng)20天新高與創(chuàng)20天新低之間畫直線并且向右延長。

DRAWLINE是唯一一個一句里面用到兩個COND的繪圖函數(shù)。因為它需要兩個點來決定一直線。

COND1相當(dāng)于指定K線位置（橫坐標(biāo)），PRICE1相當(dāng)于是指定價位（縱坐標(biāo)），這樣一個點在平面上的位置就決定了。

DRAWLINE是從第一點畫到第二點的，即有起點與終點的順序關(guān)系：第一點出現(xiàn)的時間，要在第二點之前。否則線是畫不出來的。

EXPAND，擴張、發(fā)展，這里是延伸的意思吧。一般取0，不延長；取1，延長。實際上是取大于等于1的數(shù)就延長，小于1就不延長。

DRAWLINE目前支持POINTDOT、LINETHICK、COLOR、SHIFT這四個描述函數(shù)。

舉個例子吧。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;

D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

E:=D>REF(D,1);

F:=BACKSET(E,REF(BARSLAST(B),1)+2);

G:=F>REF(F,1);

DRAWLINE(G,H,E,H,1),pointdot,linethick1,coloryellow;{主圖疊加}



這根線有些趨勢線的意思了。由于趨勢線的主觀性頗強，只有多設(shè)參數(shù)才能滿足多數(shù)人的要求，以后有機會再作介紹。

DRAWLINE畫出的線，應(yīng)該比手工畫出的線精確一些。（DRAWLINE畫線的靈敏度，要比手工畫線低，所以說DRAWLINE畫出的線精確，就未必對。）

主要用于畫斜線，水平線我們一般可以另想辦法。因為在圖中顯示直線，并非DRAWLINE的“專利”。

比如：

A:="FENG2.LD";

B:="FENG2.HD";

D:=BACKSET(ISLASTPERIOD,BARSLAST(A)+1);

E:=D>REF(D,1);

F:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

G:=F>REF(F,1);

前高:REF(H,BARSLAST(G));

前低:REF(L,BARSLAST(E));{主圖疊加}



這里出個“難題”吧：

怎么在主圖上畫一根直線？直線的高度是今天收盤價。就是這個樣子的：



三、

函數(shù)： DRAWTEXT

參數(shù)： 無

用法： DRAWTEXT(COND,PRICE,TEXT),當(dāng)COND條件滿足時,在PRICE位置書寫文字TEXT,可顯示多行文本，用"\n"換行。

說明： 在圖形上顯示文字。

示例： DRAWTEXT(CLOSE/OPEN>1.08,LOW,'大陽線')；表示當(dāng)日漲幅大于8%時在最低價位置顯示'大陽線'字樣。

DRAWTEXT(CLOSE/OPEN>1.08,LOW,'好呀\n大漲啦')；可顯示多行文本，用"\n"換行；

在某些滿足條件的地方直接顯示文字或字符，比顯示圖標(biāo)要更直觀一些。

此函數(shù)可以用ALIGN來定位水平位置。而ALIGN用在DRAWICON上定位的是高低的位置。

從下面例子可以看到，ALIGN(0~2)定義水平位置的意義：

ALIGN0：居中；

ALIGN1：偏右；

ALIGN2：偏左。

也可以用SHIFT函數(shù)進行向右水平移位。

所顯示的文字或字符，可以用COLOR函數(shù)來定義顏色。至于文字的大小，則采用系統(tǒng)默認(rèn)的大小，在此函數(shù)中無法定義。

此函數(shù)單獨使用有其用途，與DRAWNUMBER配合應(yīng)用時，效果更不錯。后面介紹到DRAWNUMBER時再舉例子。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;

D1:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

E1:=D1>REF(D1,1);{離目前最近的一個高點}

D2:=BACKSET(E1,REF(BARSLAST(B),1)+2);

E2:=D2>REF(D2,1);{倒數(shù)第二個高點}

D3:=BACKSET(E2,REF(BARSLAST(B),1)+2);

E3:=D3>REF(D3,1);{倒數(shù)第三個高點}

DRAWTEXT(E1,H*1.01,'☆TEXT:'),COLORRED,ALIGN0;

DRAWTEXT(E2,H*1.01,'★TEXT:'),COLORGREEN,ALIGN1;

DRAWTEXT(E3,H*1.01,'▓TEXT:'),COLORYELLOW,ALIGN2;{主圖疊加}



四、

函數(shù)： POLYLINE

參數(shù)： 無

用法： POLYLINE(COND,PRICE),當(dāng)COND條件滿足時,以PRICE位置為頂點畫折線連接。

說明： 在圖形上繪制折線段。

示例： POLYLINE(HIGH>=HHV(HIGH,20),HIGH)；表示在創(chuàng)20天新高點之間畫折線。

POLY，多個的。

支持POINTDOT、LINETHICK、COLOR、SHIFT這四個描述函數(shù)。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;

POLYLINE(A,L),POINTDOT,COLORGREEN;

POLYLINE(B,H),LINETHICK2,COLORMAGENTA;{主圖疊加}



五、

函數(shù)： STICKLINE

參數(shù)： 無

用法： STICKLINE(COND,PRICE1,PRICE2,WIDTH,EMPTY),當(dāng)COND條件滿足時,在PRICE1和PRICE2位置之間畫柱狀線，寬度為WIDTH可為0---100(10為標(biāo)準(zhǔn)間距),EMPTH不為0則畫空心柱。

說明： 在圖形上繪制柱線。  

示例： STICKLINE(CLOSE>OPEN,CLOSE,OPEN,0.8,1)；表示畫K線中陽線的空心柱體部分。

再說明三點：

1、PRICE1和PRICE2沒有順序關(guān)系，即何者在前何者在后都不影響語句的執(zhí)行。

2、WIDTH寬度，支持小數(shù)。用1和用0.1，會有很大的差別。取7時和主圖的K線寬度差不多。

以下的副圖公式，畫出的K線，與主圖中顯示的K線差不多。有些“主圖疊加公式”，疊加在副圖中也未嘗不可了。

STICKLINE(C>O OR (C=O AND C>REF(C,1)),O,C,7,1),colorred;{畫出紅K實體}

STICKLINE((C>O AND C<>H) OR (C=O AND C>REF(C,1)),C,H,0.1,0),colorred;{畫出紅K上影線}

STICKLINE((C>O AND L<>O) OR (C=O AND C>REF(C,1)),L,O,0.1,0),colorred;{畫出紅K下影線}

STICKLINE(C<O OR (C=O AND C<=REF(C,1)),C,O,7,0),colorcyan;{畫出青K實體}

STICKLINE(C<O OR (C=O AND C<=REF(C,1)),L,H,0.1,0),colorcyan;{畫出青K影線。因為青K是實心的，所以影線從中穿過}

MA(C,5);



3、用STICKLINE可以用兩種方法做出多色彩K線效果。

一種是橫向的，將K線實體從O到C分為N等份，每個小格中放入不同的但比較連續(xù)的顏色。

這里隨便舉個例子，N取4，只對陽線加了效果。其它變化，道理是一樣的。

A:=C-O;

B:=C>O;

STICKLINE(B,O,O+A/4,8,0),COLORFF99FF;

STICKLINE(B,O+A/4,O+A*2/4,8,0),COLORFF00FF;

STICKLINE(B,O+A*2/4,O+A*3/4,8,0),COLOR9900FF;

STICKLINE(B,O+A*3/4,O+A,8,0),COLOR0000FF;{主圖疊加}



還有一種方法就是縱向的了。先在較寬的K線中加顏色，然后把寬度逐步收窄，再加顏色覆蓋以前的的，這樣從縱向看，一根K線中就有不同顏色了。效果做得好的，可以做到賞心悅目。

B:=C>O;

STICKLINE(B,O,C,8,0),COLORFF99FF;

STICKLINE(B,O,C,6,0),COLORFF00FF;

STICKLINE(B,O,C,4,0),COLOR9900FF;

STICKLINE(B,O,C,2,0),COLOR0000FF;{主圖疊加}



六、

函數(shù)： DRAWNUMBER(COND,PRICE,NUMBER,PRECISION)

參數(shù)： NUMBER（可以為常數(shù)或數(shù)組序列）,PRECISION為精度(取值范圍0-3),即顯示到小數(shù)點后PRECISION位。

用法： DRAWNUMBER(COND,PRICE,NUMBER,PRECISION),當(dāng)COND條件滿足時,在PRICE位置書寫數(shù)字

說明： 在圖形上顯示數(shù)字。

示例： DRAWNUMBER(CLOSE/OPEN>1.08,HIGH,(CLOSE-OPEN)/OPEN*100,2)；表示當(dāng)日漲幅大于8%時在最低價位置顯示漲幅(相對開盤價的百分比)。

這個函數(shù)的特色是，在NUMBER位置可以放變量。

NUMBER,數(shù)字。DRAWNUMBER是DRAWTEXT的“兄弟”，也可以用ALIGN(0~2)來定義水平位置，方法相同。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;

D1:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

E1:=D1>REF(D1,1);{離目前最近的一個高點}

D2:=BACKSET(E1,REF(BARSLAST(B),1)+2);

E2:=D2>REF(D2,1);{倒數(shù)第二個高點}

DRAWTEXT(E1,H*1.02,'高點價：'),COLORGREEN,ALIGN2;

DRAWNUMBER(E1,H*1.02,H,2),COLORGREEN,ALIGN1;

DRAWTEXT(E2,H*1.02,'高點價：'),COLORYELLOW,ALIGN2;

DRAWNUMBER(E2,H*1.02,H,2),COLORYELLOW,ALIGN1;{主圖疊加}



七、

函數(shù)： FILLRGN(COND,PRICE1,PRICE2)

參數(shù)：   

用法： FILLRGN(COND,PRICE1,PRICE2),當(dāng)COND條件滿足時,以COLOR填充PRICE1和PRICE2的區(qū)間

說明： 繪制指標(biāo)區(qū)間彩帶。

示例： FILLRGN(MA1>MA2, MA1,MA2),colorred； 表示MA1>MA2時以紅色填充MA1和MA2之間的區(qū)域。

FILL，充滿，填充。RGN可能是REGION，地區(qū)，地域。

用這個函數(shù)，再加DRAWICON可以調(diào)用BMP圖象文件的功能，可以作出象風(fēng)景一樣的圖。

這里舉個簡單的例子：

A:=MA(C,5);

B:=MA(C,10);

FILLRGN(1,H*1.01,H*1.02),COLORFFFF66;

FILLRGN(A>=B,A,B),COLORMAGENTA;

FILLRGN(A<B,A,B),COLORGREEN;

FILLRGN(1,L*0.99,L*0.98),COLORFF99CC;{主圖疊加}

416

八、

函數(shù)： PARTLINE(COND,PRICE)

參數(shù)：   

用法： PARTLINE(COND,PRICE),滿足COND條件繪制PRICE連線。

說明： 分段繪制指標(biāo)線

示例： PARTLINE(C>REF(C,1),C),colorred；表示收盤大于前收以紅色繪制收盤價連線。

PART，部分，局部。值得一提的是，PARTLINE支持多種描述函數(shù)，如例所見。

A:=MA(C,5);

B:=MA(C,10);

PARTLINE(A>=B,A),COLORRED,POINTDOT;

PARTLINE(A>=B,B),COLORGREEN,CIRCLEDOT;

PARTLINE(A<B,A),COLORGREEN,CROSSDOT,LINETHICK3;

PARTLINE(A<B,B),COLORRED,SHIFT2;{主圖疊加}



九、

函數(shù)： VERTLINE(COND)

參數(shù)：   

用法： VERTLINE(COND),在COND條件滿足的周期處畫垂直線

說明： 在圖形上繪制垂直線段

示例： DVERTLINE(HIGH>=HHV(HIGH,20)；表示在創(chuàng)20天新高時畫垂直線

VERTICAL，垂直的。

VERTLINE目前可以用POINTDOT、LINETHICK、COLOR、SHIFT這四個描述函數(shù)來描述。

這個函數(shù)，主要是用于畫線看時間的。費波納契周期，可以用這個函數(shù)畫出來的。

這里舉個例子，把日K線中每月的第一個交易日中，畫一根垂直線。

A:=MONTH>REF(MONTH,1);

VERTLINE(A),COLOR808040,POINTDOT;{主圖疊加}



十、

函數(shù)： DRAWYITEXT(COND,PRICE,CODE,TYPE)

參數(shù)：        

用法： 在COND在圖形上顯示易學(xué)文字,可ALIGN0-3定義對齊方式。

說明： 當(dāng)COND條件滿足時,在PRICE位置書寫TYPE類型的CODE的對應(yīng)文字
TYPE為常數(shù)，取0--1，分別表示計算的是干支、64卦，CODE為對應(yīng)的代碼



示例： DRAWYITEXT(CLOSE/OPEN>1.05,LOW, GANZHI(DATE*100, 2),0)，表示當(dāng)日漲幅大于5%時在最低價位置顯示日干支；
DRAWYITEXT(REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)>REF(OPEN,1) AND CLOSE>OPEN, LOW, KGUA(1, 1), 1 )，表示連二陽時在最低價位置顯示K線卦象。

如下例子：K線卦

kk:=KGUA(0,6);
DRAWYITEXT(c>0,mod(BARSCOUNT(c),6),kk,1); {附圖指標(biāo)}



十一、

函數(shù)： DRAWBKBMP(COND,BMP)

參數(shù)：        

用法: 當(dāng)圖形上最后一組COND條件滿足時,以MyBMP做背景：        

說明： 根據(jù)條件設(shè)置背景圖

示例： 因為系統(tǒng)K線先畫，會被后來的指標(biāo)圖覆蓋了

這種公式K線要自己畫，以下供參考


DRAWBKBMP(c>0,'mybmp');
STICKLINE(c>o or c=o and c>ref(c,1),l,h,0.1,0),colorred;
STICKLINE(c>o or c=o and c>ref(c,1),o,c,7,0),colorred;

STICKLINE(c<o or c=o and c<=ref(c,1),l,h,0.1,0),colorcyan;
STICKLINE(c<o or c=o and c<=ref(c,1),o,c,7,0),colorcyan;

把公式設(shè)為主圖、主圖疊加



十二、

函數(shù)： DRAWGBK(COND,COLOR1, COLOR2,D)

參數(shù)：   

用法： 當(dāng)COND條件滿足時,以COLOR1到COLOR2漸變色填充子圖區(qū)域,D=0表示從左到右,D=1表示從上到下

說明： 繪制漸變背景色

示例： DRAWGBK(C>O, COLORRGB(255,0,0), COLORRGB(255,255,0),0);
表示圖形上最后一組C>O時從左到右從紅色到黃色漸變填充子圖。

 

飛狐基本函數(shù)簡介之時間函數(shù)

飛狐基本函數(shù)簡介之引用函數(shù)